pkgname=cpio
pkgver=2.15
pkgrel=1
pkgdesc="A tool to copy files into or out of a cpio or tar archive"
arch=('x86_64')
url="https://www.gnu.org/software/cpio"
license=('GPL-3.0-or-later')
depends=('glibc')
source=(https://ftp.gnu.org/gnu/${pkgname}/${pkgname}-${pkgver}.tar.bz2)
sha256sums=(937610b97c329a1ec9268553fb780037bcfff0dcffe9725ebc4fd9c1aa9075db)

build() {
    cd ${pkgname}-${pkgver}

    local configure_args=(
        --enable-mt
        --with-rmt=/usr/libexec/rmt
        ${configure_options}
    )

    ./configure ${configure_args[@]}

    make
    makeinfo --html            -o doc/html      doc/cpio.texi
    makeinfo --html --no-split -o doc/cpio.html doc/cpio.texi
    makeinfo --plaintext       -o doc/cpio.txt  doc/cpio.texi
}

package() {
    cd ${pkgname}-${pkgver}

    make DESTDIR=${pkgdir} install

    install -v -m755 -d ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}/html
    install -v -m644    doc/html/* ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}/html
    install -v -m644    doc/cpio.{html,txt} ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}

}