pkgname=curl
pkgver=8.11.0
pkgrel=2
pkgdesc="command line tool and library for transferring data with URLs"
arch=('x86_64')
url="https://curl.se/"
license=('MIT')
depends=(
    'brotli'
    'ca-certificates'
    'krb5'
    'libidn2'
    'libpsl'
    'libssh2'
    'nghttp2'
    'openssl'
    'zlib'
    'zstd'
)
source=(https://curl.se/download/${pkgname}-${pkgver}.tar.xz)
sha256sums=(db59cf0d671ca6e7f5c2c5ec177084a33a79e04c97e71cf183a5cdea235054eb)

build() {
    cd ${pkgname}-${pkgver}

    local configure_args=(
        --disable-static
        --with-openssl
        --with-ca-path=/etc/ssl/certs
        --with-libpsl
        --with-nghttp2
        --with-libssh2
        --with-gssapi
        ${configure_options}
    )

    ./configure ${configure_args[@]}

    make
}

package() {
    cd ${pkgname}-${pkgver}

    make DESTDIR=${pkgdir} install

    find docs \( -name Makefile\* -o  \
                 -name \*.1       -o  \
                 -name \*.3       -o  \
                 -name CMakeLists.txt \) -delete

    install -vdm755 ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
    cp -v -R docs -T ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
}