pkgname=curl
pkgver=8.11.0
pkgrel=1
pkgdesc="command line tool and library for transferring data with URLs"
arch=('x86_64')
url="https://curl.se/"
license=('MIT')
depends=('openssl' 'zlib' 'zstd' 'libidn2' 'libpsl' 'nghttp2' 'libssh2' 'ca-certificates')
source=(https://curl.se/download/${pkgname}-${pkgver}.tar.xz)
sha256sums=(db59cf0d671ca6e7f5c2c5ec177084a33a79e04c97e71cf183a5cdea235054eb)

build() {
    cd ${pkgname}-${pkgver}

    ./configure                        \
        --disable-static               \
        --with-openssl                 \
        --with-ca-path=/etc/ssl/certs  \
        --with-libpsl                  \
        --with-nghttp2                 \
        --with-libssh2                 \
        ${configure_options}

    make
}

package() {
    cd ${pkgname}-${pkgver}

    make DESTDIR=${pkgdir} install

    find docs \( -name Makefile\* -o  \
                 -name \*.1       -o  \
                 -name \*.3       -o  \
                 -name CMakeLists.txt \) -delete

    install -vdm755 ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
    cp -v -R docs -T ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
}