pkgname=dbus
pkgver=1.16.0
pkgrel=1
pkgdesc="Freedesktop.org message bus system"
arch=('x86_64')
url="https://wiki.freedesktop.org/www/Software/dbus/"
license=('AFL-2.1 OR GPL-2.0-or-later')
depends=('expat' 'coreutils' 'filesystem' 'shadow') 
makedepends=('python' 'systemd' 'meson')
source=(https://dbus.freedesktop.org/releases/${pkgname}/${pkgname}-${pkgver}.tar.xz
    dbus-reload.hook)
sha256sums=(9f8ca5eb51cbe09951aec8624b86c292990ae2428b41b856e2bed17ec65c8849
    d636205622d0ee3b0734360225739ef0c7ad2468a09489e6ef773d88252960f3)

build() {
    cd ${pkgname}-${pkgver}

    local meson_args=(
        --wrap-mode=nofallback
        -Dselinux=disabled
    )

    ${meson_options} ${meson_args[@]}

    ${meson_build}
}

package() {
    cd ${pkgname}-${pkgver}

    ${meson_install} ${pkgdir}

    ln -sfv /etc/machine-id ${pkgdir}/var/lib/dbus

    rm -rvf ${pkgdir}/var/run
    rm -rvf ${pkgdir}/run

    chown -v root:messagebus ${pkgdir}/usr/libexec/dbus-daemon-launch-helper
    chmod -v      4750       ${pkgdir}/usr/libexec/dbus-daemon-launch-helper

    mv -v ${pkgdir}/usr/share/doc/${pkgname}{,-${pkgver}}

    install -Dm644 ${srcdir}/dbus-reload.hook ${pkgdir}/usr/share/libalpm/hooks/dbus-reload.hook
}