pkgname=(
    gcc
    gcc-libs
    gcc-libs-32bit
    gcc-fortran
    gcc-go
    gcc-m2
    gcc-objc
    lto-dump
    libgccjit
)
pkgver=14.2.1+r134+gab884fffe3fc
pkgrel=1
pkgdesc="The GNU Compiler Collection"
arch=('x86_64')
license=('GPL-3.0-with-GCC-exception' 'GFDL-1.3-or-later')
url="https://gcc.gnu.org"
makedepends=(
    'binutils'
    'git'
    'glibc-32bit'
    'gcc-libs-32bit'
    'isl'
    'mpc'
    'python'
    'zstd'
)
options=('!emptydirs' '!lto')
source=(git+https://mirrors.tuna.tsinghua.edu.cn/git/gcc.git#commit=ab884fffe3fc82a710bea66ad651720d71c938b8
    c89
    c99)
sha256sums=(SKIP
    aa3327fd8626acf2a28fa75c0b3ed99fcffb1bbcbe6974505f050ee751ba4154
    2861971c0ef2c011ce10c98e8cf7b5fd1d3d3c4eddcfe0a01ed9d76940f67638)

pkgver() {
    cd gcc

    echo "$(cat gcc/BASE-VER)+$(git describe --abbrev=12 --tags | sed 's/[^-]*-[^-]*-//;s/[^-]*-/r&/;s/-/+/g;s/_/./')"
}

prepare() {
    cd gcc

    # Do not run fixincludes
    sed -i 's@\./fixinc\.sh@-c true@' gcc/Makefile.in

    mkdir -p ${srcdir}/gcc-build
    mkdir -p ${srcdir}/libgccjit-build
}

build() {
    local _confflags=(
        --prefix=/usr
        --libdir=/usr/lib64
        --mandir=/usr/share/man
        --infodir=/usr/share/info
        --with-build-config=bootstrap-lto
        --with-linker-hash-style=gnu
        --with-system-zlib
        --enable-__cxa_atexit
        --enable-cet=auto
        --enable-checking=release
        --enable-clocale=gnu
        --enable-default-pie
        --enable-default-ssp
        --enable-gnu-indirect-function
        --enable-gnu-unique-object
        --enable-libstdcxx-backtrace
        --enable-link-serialization=1
        --enable-linker-build-id
        --enable-lto
        --enable-multilib
        --enable-plugin
        --enable-shared
        --enable-threads=posix
        --disable-libssp
        --disable-libstdcxx-pch
        --disable-werror
    )

    cd gcc-build

    # Credits @allanmcrae
    # https://github.com/allanmcrae/toolchain/blob/f18604d70c5933c31b51a320978711e4e6791cf1/gcc/PKGBUILD
    # TODO: properly deal with the build issues resulting from this
    CFLAGS=${CFLAGS/-Werror=format-security/}
    CXXFLAGS=${CXXFLAGS/-Werror=format-security/}

    ${srcdir}/gcc/configure \
        --enable-languages=c,c++,fortran,go,lto,m2,objc,obj-c++ \
        --enable-bootstrap \
        "${_confflags[@]:?_confflags unset}"

    # see https://bugs.archlinux.org/task/71777 for rationale re *FLAGS handling
    make -O STAGE1_CFLAGS="-O2" \
            BOOT_CFLAGS="$CFLAGS" \
            BOOT_LDFLAGS="$LDFLAGS" \
            LDFLAGS_FOR_TARGET="$LDFLAGS" \
            bootstrap

    # Build libgccjit separately, to avoid building all compilers with --enable-host-shared
    # which brings a performance penalty
    cd ${srcdir}/libgccjit-build

    ${srcdir}/gcc/configure \
        --enable-languages=jit \
        --disable-bootstrap \
        --enable-host-shared \
        "${_confflags[@]:?_confflags unset}"

    # see https://bugs.archlinux.org/task/71777 for rationale re *FLAGS handling
    make -O STAGE1_CFLAGS="-O2" \
            BOOT_CFLAGS="$CFLAGS" \
            BOOT_LDFLAGS="$LDFLAGS" \
            LDFLAGS_FOR_TARGET="$LDFLAGS" \
            all-gcc

    cp -a gcc/libgccjit.so* ../gcc-build/gcc/
}

package_gcc-libs() {
    pkgdesc="Runtime libraries shipped by GCC"
    depends=('glibc')
    options=('!emptydirs' '!strip')

    cd gcc-build

    make -C ${CHOST}/libgcc DESTDIR=${pkgdir} install-shared

    rm -f ${pkgdir}/usr/lib64/gcc/${CHOST}/${pkgver%%+*}/libgcc_eh.a

    for lib in libatomic \
            libgfortran \
            libgo \
            libgomp \
            libitm \
            libquadmath \
            libsanitizer/{a,l,ub,t}san \
            libstdc++-v3/src \
            libvtv
    do
        make -C ${CHOST}/${lib} DESTDIR=${pkgdir} install-toolexeclibLTLIBRARIES
    done

    make -C ${CHOST}/libobjc DESTDIR=${pkgdir} install-libs
    make -C ${CHOST}/libstdc++-v3/po DESTDIR=${pkgdir} install

    for lib in libgomp \
            libitm \
            libquadmath
    do
        make -C ${CHOST}/${lib} DESTDIR=${pkgdir} install-info
    done

    # remove files provided by gcc-libs-32bit
    rm -rf ${pkgdir}/usr/lib32/
}

package_gcc() {
    pkgdesc="The GNU Compiler Collection - C and C++ frontends"
    depends=("gcc-libs=${pkgver}-${pkgrel}" 'binutils' 'mpc' 'zstd' 'isl')
    options=('!emptydirs' '!staticlibs')

    cd gcc-build

    make -C gcc DESTDIR=${pkgdir} install-driver install-cpp install-gcc-ar \
    c++.install-common install-headers install-plugin install-lto-wrapper

    install -m755 -t ${pkgdir}/usr/bin/ gcc/gcov{,-tool}
    install -m755 -t ${pkgdir}/usr/libexec/gcc/${CHOST}/${pkgver%%+*}/ gcc/{cc1,cc1plus,collect2,lto1}

    make -C ${CHOST}/libgcc DESTDIR=${pkgdir} install
    make -C ${CHOST}/32/libgcc DESTDIR=${pkgdir} install

    rm -f ${pkgdir}/usr/lib{32,64}/libgcc_s.so*

    make -C ${CHOST}/libstdc++-v3/src DESTDIR=${pkgdir} install
    make -C ${CHOST}/libstdc++-v3/include DESTDIR=${pkgdir} install
    make -C ${CHOST}/libstdc++-v3/libsupc++ DESTDIR=${pkgdir} install
    make -C ${CHOST}/libstdc++-v3/python DESTDIR=${pkgdir} install

    make -C ${CHOST}/32/libstdc++-v3/src DESTDIR=${pkgdir} install
    make -C ${CHOST}/32/libstdc++-v3/include DESTDIR=${pkgdir} install
    make -C ${CHOST}/32/libstdc++-v3/libsupc++ DESTDIR=${pkgdir} install

    make DESTDIR=${pkgdir} install-libcc1

    install -d ${pkgdir}/usr/share/gdb/auto-load/usr/lib64
    mv ${pkgdir}/usr/lib64/libstdc++.so.6.*-gdb.py ${pkgdir}/usr/share/gdb/auto-load/usr/lib64/

    rm ${pkgdir}/usr/lib{32,64}/libstdc++.so*

    make DESTDIR=${pkgdir} install-fixincludes

    make -C gcc DESTDIR=${pkgdir} install-mkheaders
    make -C lto-plugin DESTDIR=${pkgdir} install

    install -dm755 ${pkgdir}/usr/lib64/bfd-plugins/
    ln -s /usr/libexec/gcc/${CHOST}/${pkgver%%+*}/liblto_plugin.so ${pkgdir}/usr/lib64/bfd-plugins/

    make -C ${CHOST}/libgomp DESTDIR=${pkgdir} install-nodist_{libsubinclude,toolexeclib}HEADERS
    make -C ${CHOST}/libitm DESTDIR=${pkgdir} install-nodist_toolexeclibHEADERS
    make -C ${CHOST}/libquadmath DESTDIR=${pkgdir} install-nodist_libsubincludeHEADERS
    make -C ${CHOST}/libsanitizer DESTDIR=${pkgdir} install-nodist_{saninclude,toolexeclib}HEADERS
    make -C ${CHOST}/libsanitizer/asan DESTDIR=${pkgdir} install-nodist_toolexeclibHEADERS
    make -C ${CHOST}/libsanitizer/tsan DESTDIR=${pkgdir} install-nodist_toolexeclibHEADERS
    make -C ${CHOST}/libsanitizer/lsan DESTDIR=${pkgdir} install-nodist_toolexeclibHEADERS

    make -C ${CHOST}/32/libgomp DESTDIR=${pkgdir} install-nodist_toolexeclibHEADERS
    make -C ${CHOST}/32/libitm DESTDIR=${pkgdir} install-nodist_toolexeclibHEADERS
    make -C ${CHOST}/32/libsanitizer DESTDIR=${pkgdir} install-nodist_{saninclude,toolexeclib}HEADERS
    make -C ${CHOST}/32/libsanitizer/asan DESTDIR=${pkgdir} install-nodist_toolexeclibHEADERS

    make -C gcc DESTDIR=${pkgdir} install-man install-info

    rm ${pkgdir}/usr/share/man/man1/{gccgo,gfortran,lto-dump,gm2}.1
    rm ${pkgdir}/usr/share/info/{gccgo,gfortran,m2}.info

    make -C libcpp DESTDIR=${pkgdir} install
    make -C gcc DESTDIR=${pkgdir} install-po

    # many packages expect this symlink
    ln -s gcc ${pkgdir}/usr/bin/cc

    # create cc-rs compatible symlinks
    # https://github.com/rust-lang/cc-rs/blob/1.0.73/src/lib.rs#L2578-L2581
    for binary in {c++,g++,gcc,gcc-ar,gcc-nm,gcc-ranlib}; do
        ln -s /usr/bin/${binary} ${pkgdir}/usr/bin/x86_64-linux-gnu-${binary}
    done
    # POSIX conformance launcher scripts for c89 and c99
    install -Dm755 ${srcdir}/c89 ${pkgdir}/usr/bin/c89
    install -Dm755 ${srcdir}/c99 ${pkgdir}/usr/bin/c99

    # install the libstdc++ man pages
    # make -C ${CHOST}/libstdc++-v3/doc DESTDIR=${pkgdir} doc-install-man

    # remove files provided by lib32-gcc-libs
    rm -f ${pkgdir}/usr/lib32/lib{stdc++,gcc_s}.so

    # byte-compile python libraries
    python3 -m compileall ${pkgdir}/usr/share/gcc-${pkgver%%+*}/
    python3 -O -m compileall ${pkgdir}/usr/share/gcc-${pkgver%%+*}/
}

package_gcc-fortran() {
    pkgdesc="Fortran front-end for GCC"
    depends=("gcc=${pkgver}-${pkgrel}" 'isl')

    cd gcc-build

    make -C ${CHOST}/libgfortran DESTDIR=${pkgdir} install-cafexeclibLTLIBRARIES \
    install-{toolexeclibDATA,nodist_fincludeHEADERS,gfor_cHEADERS}

    make -C ${CHOST}/32/libgfortran DESTDIR=${pkgdir} install-cafexeclibLTLIBRARIES \
    install-{toolexeclibDATA,nodist_fincludeHEADERS,gfor_cHEADERS}

    make -C ${CHOST}/libgomp DESTDIR=${pkgdir} install-nodist_fincludeHEADERS
    make -C gcc DESTDIR=${pkgdir} fortran.install-{common,man,info}

    install -Dm755 gcc/f951 ${pkgdir}/usr/libexec/gcc/${CHOST}/${pkgver%%+*}/f951
    ln -s gfortran ${pkgdir}/usr/bin/f95
}

package_gcc-objc() {
    pkgdesc="Objective-C front-end for GCC"
    depends=("gcc=${pkgver}-${pkgrel}" 'isl')

    cd gcc-build

    sed -i "/^libdir/s/lib$/lib64/" ${CHOST}/libobjc/Makefile

    make DESTDIR=${pkgdir} -C ${CHOST}/libobjc install-headers

    install -dm755 ${pkgdir}/usr/libexec/gcc/${CHOST}/${pkgver%%+*}
    install -m755 gcc/cc1obj{,plus} ${pkgdir}/usr/libexec/gcc/${CHOST}/${pkgver%%+*}/
}

package_gcc-go() {
    pkgdesc="Go front-end for GCC"
    depends=("gcc=${pkgver}-${pkgrel}" 'isl')

    cd gcc-build

    make -C ${CHOST}/libgo DESTDIR=${pkgdir} install-exec-am

    make -C ${CHOST}/32/libgo DESTDIR=${pkgdir} install-exec-am

    make DESTDIR=${pkgdir} install-gotools
    make -C gcc DESTDIR=${pkgdir} go.install-{common,man,info}

    rm -f ${pkgdir}/usr/lib{32,64}/libgo.so*
    install -Dm755 gcc/go1 ${pkgdir}/usr/libexec/gcc/${CHOST}/${pkgver%%+*}/go1
}

package_gcc-libs-32bit() {
    pkgdesc="32-bit runtime libraries shipped by GCC"
    depends=('glibc-32bit')
    options=('!emptydirs' '!strip')

    cd gcc-build

    make -C ${CHOST}/32/libgcc DESTDIR=${pkgdir} install-shared

    rm -f ${pkgdir}/usr/lib64/gcc/${CHOST}/${pkgver%%+*}/32/libgcc_eh.a

    for lib in libatomic \
            libgfortran \
            libgo \
            libgomp \
            libitm \
            libquadmath \
            libsanitizer/{a,l,ub}san \
            libstdc++-v3/src \
            libvtv
    do
        make -C ${CHOST}/32/${lib} DESTDIR=${pkgdir} install-toolexeclibLTLIBRARIES
    done

    make -C ${CHOST}/32/libobjc DESTDIR=${pkgdir} install-libs
    rm -f ${pkgdir}/usr/lib32/libgphobos.spec

    # remove files provided by gcc-libs
    rm -rf ${pkgdir}/usr/lib64
}

package_gcc-m2() {
    pkgdesc="Modula-2 frontend for GCC"
    depends=("gcc=${pkgver}-${pkgrel}" 'isl')

    cd gcc-build

    make -C gcc DESTDIR=${pkgdir} m2.install-{common,man,info}

    install -Dm755 gcc/cc1gm2 ${pkgdir}/usr/libexec/gcc/${CHOST}/${pkgver%%+*}/cc1gm2
    install -Dm755 gcc/gm2 ${pkgdir}/usr/bin/gm2

    make -C ${CHOST}/libgm2 DESTDIR=${pkgdir} install

}

package_lto-dump() {
    pkgdesc="Dump link time optimization object files"
    depends=("gcc=${pkgver}-${pkgrel}" 'isl')

    cd gcc-build

    make -C gcc DESTDIR=${pkgdir} lto.install-{common,man,info}
}

package_libgccjit() {
    pkgdesc="Just-In-Time Compilation with GCC backend"
    depends=("gcc=${pkgver}-${pkgrel}" 'isl')

    cd gcc-build

    make -C gcc DESTDIR=${pkgdir} jit.install-common jit.install-info
}