pkgname=guile
pkgver=3.0.10
pkgrel=1
pkgdesc="Portable, embeddable Scheme implementation written in C"
arch=('x86_64')
url="https://www.gnu.org/software/guile"
license=('GPL')
depends=('gmp' 'ncurses' 'libunistring' 'gc' 'libffi' 'libxcrypt')
makedepends=('texinfo')
source=(https://ftp.gnu.org/gnu/${pkgname}/${pkgname}-${pkgver}.tar.xz)
sha256sums=(bd7168517fd526333446d4f7ab816527925634094fbd37322e17e2b8d8e76388)

build() {
    cd ${pkgname}-${pkgver}

    local configure_args=(
        --disable-static
        --docdir=/usr/share/doc/${pkgname}-${pkgver}
        ${configure_options}
    )

    ./configure ${configure_args[@]}

    make
    make html

    makeinfo --plaintext -o doc/r5rs/r5rs.txt doc/r5rs/r5rs.texi
    makeinfo --plaintext -o doc/ref/guile.txt doc/ref/guile.texi
}

package() {
    cd ${pkgname}-${pkgver}

    make DESTDIR=${pkgdir} install
    make DESTDIR=${pkgdir} install-html

    install -vdm755 ${pkgdir}/usr/share/gdb/auto-load/usr/lib64
    mv ${pkgdir}/usr/lib64/libguile-*-gdb.scm ${pkgdir}/usr/share/gdb/auto-load/usr/lib64

    mv ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}/{guile.html,ref}
    mv ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}/r5rs{.html,}

    find examples -name "Makefile*" -delete
    cp -vR examples   ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}

    for DIRNAME in r5rs ref; do
        install -v -m644  doc/${DIRNAME}/*.txt ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
    done 
}