pkgname=kbd
pkgver=2.7.1
pkgrel=1
pkgdesc="Keytable files and keyboard utilities"
arch=('x86_64')
url="https://kbd-project.org/"
license=('GPL-2.0-or-later')
depends=('glibc' 'gzip' 'linux-pam')
makedepends=('check')
backup=(etc/pam.d/vlock)
source=(https://www.kernel.org/pub/linux/utils/${pkgname}/${pkgname}-${pkgver}.tar.xz
    https://www.linuxfromscratch.org/patches/downloads/${pkgname}/${pkgname}-${pkgver}-backspace-1.patch)
sha256sums=(f167d899d92b56ccf12f6f49355173f93870a95f15d8aeebf5fdcd28a621aca8
    8be28dcb11420624a500f2ea4fe975f771174bffee50e54ec8cd295a2dec104e)

prepare() {
    cd ${pkgname}-${pkgver}

    patch -Np1 -i ${srcdir}/${pkgname}-${pkgver}-backspace-1.patch

    sed -i '/RESIZECONS_PROGS=/s/yes/no/' configure
    sed -i 's/resizecons.8 //' docs/man/man8/Makefile.in
}

build() {
    cd ${pkgname}-${pkgver}

    local configure_args=(
        --sysconfdir=/etc
        --enable-vlock
        ${configure_options}
    )

    ./configure ${configure_args[@]}

    make
}

package() {
    cd ${pkgname}-${pkgver}

    make DESTDIR=${pkgdir} install

    install -vdm755 ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
    cp -R -v docs/doc -T ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
}