pkgname=libgcrypt
pkgver=1.11.0
pkgrel=1
pkgdesc="General purpose cryptographic library based on the code from GnuPG"
arch=('x86_64')
url="https://www.gnupg.org"
license=('BSD-3-Clause'
    'BSD-3-Clause OR GPL-2.0-only'
    'GPL-2.0-or-later'
    'LGPL-2.0-or-later'
    'LGPL-2.1-or-later'
    'X11'
    'LicenseRef-scancode-public-domain'
    'LicenseRef-OCB1')
depends=('libgpg-error')
options=('!emptydirs')
source=(https://www.gnupg.org/ftp/gcrypt/${pkgname}/${pkgname}-${pkgver}.tar.bz2)
sha256sums=(09120c9867ce7f2081d6aaa1775386b98c2f2f246135761aae47d81f58685b9c)

build() {
    cd ${pkgname}-${pkgver}

    local configure_args=(
        --disable-static
        ${configure_options}
    )

    ./configure ${configure_args[@]}

    make
    make -C doc html
    makeinfo --html --no-split -o doc/gcrypt_nochunks.html doc/gcrypt.texi
    makeinfo --plaintext       -o doc/gcrypt.txt           doc/gcrypt.texi
}

package() {
    cd ${pkgname}-${pkgver}

    make DESTDIR=${pkgdir} install

    install -v -dm755   ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
    install -v -m644    README doc/{README.apichanges,fips*,libgcrypt*} ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}

    install -v -dm755   ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}/html
    install -v -m644 doc/gcrypt.html/* ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}/html
    install -v -m644 doc/gcrypt_nochunks.html ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
    install -v -m644 doc/gcrypt.{txt,texi} ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
}