pkgname=pacman
pkgver=7.0.0
pkgrel=1
pkgdesc="A library-based package manager with dependency support"
arch=('x86_64')
url="https://www.archlinux.org/pacman/"
license=('GPL-2.0-or-later')
groups=('base' 'base-devel')
depends=(
    'bash'
    'coreutils'
    'curl'
    'fakeroot'
    'gawk'
    'gettext'
    'glibc'
    'gnupg'
    'gpgme'
    'grep'
    'libarchive'
    'systemd'
)
makedepends=('meson')
backup=(etc/pacman.conf
    etc/makepkg.conf
    etc/makepkg.conf.d/_pick-options.conf
    etc/makepkg.conf.d/rust.conf)
source=(https://gitlab.archlinux.org/pacman/pacman/-/releases/v${pkgver}/downloads/${pkgname}-v${pkgver}.tar.gz
    revertme-makepkg-remove-libdepends-and-libprovides.patch::https://gitlab.archlinux.org/pacman/pacman/-/commit/354a300cd26bb1c7e6551473596be5ecced921de.patch
    alpm.sysusers
    makepkg.conf
    flarebird-build-options.conf
    pacman.conf
    rust.conf)
sha256sums=(ef08f258cb3e0885c5884ad43fb6cff0e9c327ed33024d79d03555f99c583744
    b3bce9d662e189e8e49013b818f255d08494a57e13fc264625f852f087d3def2
    c8760d7ebb6c9817d508c691c67084be251cd9c8811ee1ccf92c1278bad74c1c
    bba63f31e6f0bda04fd464fd301dedd5fbe00c154120e0d164b88e0dfbd2f733
    a03428fd00f00a64848d4aac928bdf4cf077ae66e17e09900e9a8e962a5f0ebb
    7ff5bda0647ffd478d8cb319d560b5749ace5cbb775748de02a226f3d5a3a98a
    59a8bbdc32830c90dbce5ead9f90074a2bb31cd85ec92bc5f92251bb4bcf8a1d)

prepare() {
    cd ${pkgname}-v${pkgver}

    patch -RNp1 < ${srcdir}/revertme-makepkg-remove-libdepends-and-libprovides.patch
}

build() {
    cd ${pkgname}-v${pkgver}

    local meson_args=(
         -Dcrypto=openssl
        -Ddoc=disabled
        -Dscriptlet-shell=/usr/bin/bash
        -Dldconfig=/usr/sbin/ldconfig
        -Dpkg-ext=.pkg.tar.zst
        -Dsrc-ext=.src.tar.zst
    )

    ${meson_options} ${meson_args[@]}

    ${meson_build}
}

package() {
    cd ${pkgname}-v${pkgver}

    ${meson_install} ${pkgdir}

    install -vm644 ${srcdir}/makepkg.conf ${pkgdir}/etc
    install -vm644 ${srcdir}/pacman.conf  ${pkgdir}/etc
    install -vm644 ${srcdir}/flarebird-build-options.conf ${pkgdir}/etc/makepkg.conf.d
    install -vm644 ${srcdir}/rust.conf ${pkgdir}/etc/makepkg.conf.d

    install -vdm755 ${pkgdir}/etc/pacman.d

    install -D -m644 ${srcdir}/alpm.sysusers ${pkgdir}/usr/lib/sysusers.d/alpm.conf

    local wantsdir=${pkgdir}/usr/lib/systemd/system/sockets.target.wants
    install -dm755  ${wantsdir}

    local unit
    for unit in dirmngr gpg-agent gpg-agent-{browser,extra,ssh} keyboxd; do
        ln -sv ../${unit}@.socket ${wantsdir}/${unit}@etc-pacman.d-gnupg.socket
    done
}