pkgname=pcre2
pkgver=10.44
pkgrel=1
pkgdesc="A library that implements Perl 5-style regular expressions. 2nd version"
arch=('x86_64')
url="https://www.pcre.org/"
license=('BSD-3-Clause')
depends=('bzip2' 'glibc' 'readline' 'zlib')
source=(https://github.com/PCRE2Project/pcre2/releases/download/${pkgname}-${pkgver}/${pkgname}-${pkgver}.tar.bz2)
sha256sums=(d34f02e113cf7193a1ebf2770d3ac527088d485d4e047ed10e5d217c6ef5de96)

build() {
    cd ${pkgname}-${pkgver}

    CFLAGS+=" -ffat-lto-objects"
    CXXFLAGS+=" -ffat-lto-objects"

    local configure_args=(
        --enable-unicode
        --enable-jit
        --enable-pcre2-16
        --enable-pcre2-32
        --enable-pcre2grep-libz
        --enable-pcre2grep-libbz2
        --enable-pcre2test-libreadline
        --disable-static
        --docdir=/usr/share/doc/${pkgname}-${pkgver}
        ${configure_options}
    )

    ./configure ${configure_args[@]}

    make
}

package() {
    cd ${pkgname}-${pkgver}

    make DESTDIR=${pkgdir} install
}