pkgname=pkgconf
pkgver=2.3.0
pkgrel=1
pkgdesc="Package compiler and linker metadata toolkit"
arch=('x86_64')
url="http://pkgconf.org/"
license=('ISC')
groups=('base-devel')
depends=('glibc' 'bash')
source=(https://distfiles.ariadne.space/${pkgname}/${pkgname}-${pkgver}.tar.xz
    x86_64-flarebird-linux-gnu.personality
    i686-flarebird-linux-gnu.personality)
sha256sums=(3a9080ac51d03615e7c1910a0a2a8df08424892b5f13b0628a204d3fcce0ea8b
    ae804d52b82f97683189202f960ee89fded131fbc2cf99bbde8641e180b273b1
    028a099184a7821d8d8ea30f7c140ee0734fc859bccb0c9bb886d9d99b09b840)

build() {
    cd ${pkgname}-${pkgver}

    local configure_args=(
        --disable-static
        --docdir=/usr/share/doc/${pkgname}-${pkgver}
        ${configure_options}
    )

    ./configure ${configure_args[@]}

    make
}

package() {
    cd ${pkgname}-${pkgver}

    make DESTDIR=${pkgdir} install

    ln -sv pkgconf ${pkgdir}/usr/bin/pkg-config

    for p in {x86_64,i686}-flarebird-linux-gnu; do
        install -Dt ${pkgdir}/usr/share/pkgconfig/personality.d -m644 ${srcdir}/${p}.personality
        ln -sv pkgconf ${pkgdir}/usr/bin/${p}-pkg-config
    done

    ln -sv pkgconf.1 ${pkgdir}/usr/share/man/man1/pkg-config.1
}