pkgname=systemd
pkgver=257
pkgrel=2
pkgdesc="system and service manager"
arch=('x86_64')
url="https://www.freedesktop.org/wiki/Software/systemd/"
license=('LGPL-2.1-or-later' 'CC0-1.0' 'GPL-2.0-or-later' 'MIT-0' 'GPL-2.0-or-later WITH Linux-syscall-note')
groups=('base')
depends=(
    'acl'
    'bash'
    'binutils'
    'curl'
    'dbus'
    'filesystem'
    'gcc-libs'
    'glibc'
    'kbd'
    'kmod'
    'libcap'
    'libelf'
    'libgcrypt'
    'libidn2'
    'libseccomp'
    'libpwquality'
    'libxcrypt'
    'linux-pam'
    'lz4'
    'openssl'
    'p11-kit'
    'pcre2'
    'python-pefile'
    'python-jinja2'
    'util-linux'
    'xz'
    'zstd'
)
makedepends=(
    'bash-completion'
    'ca-certificates'
    'cryptsetup'
    'docbook-xml'
    'docbook-xsl'
    'gcc-libs-32bit'
    'git'
    'gnutls'
    'gnu-efi'
    'gperf'
    'intltool'
    'less'
    'libarchive'
    'libxslt'
    'linux-api-headers'
    'meson'
    'python-lxml'
    'python-pyelftools'
    'rsync'
    'shadow'
)
backup=(etc/pam.d/systemd-user
    etc/systemd/coredump.conf
    etc/systemd/homed.conf
    etc/systemd/journald.conf
    etc/systemd/journal-upload.conf
    etc/systemd/logind.conf
    etc/systemd/networkd.conf
    etc/systemd/oomd.conf
    etc/systemd/pstore.conf
    etc/systemd/resolved.conf
    etc/systemd/sleep.conf
    etc/systemd/system.conf
    etc/systemd/timesyncd.conf
    etc/systemd/user.conf
    etc/udev/iocost.conf
    etc/udev/udev.conf)
install=${pkgname}.install
source=(https://github.com/systemd/systemd/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz
    20-systemd-sysusers.hook
    30-systemd-binfmt.hook
    30-systemd-catalog.hook
    30-systemd-daemon-reload-system.hook
    30-systemd-daemon-reload-user.hook
    30-systemd-hwdb.hook
    30-systemd-restart-marked.hook
    30-systemd-sysctl.hook
    30-systemd-tmpfiles.hook
    30-systemd-udev-reload.hook
    30-systemd-update.hook
    systemd-hook
    systemd-user)
sha256sums=(14f6907eb5e289d8c39cbe1ef891ca54d8a0e3582c986a9ef5844b3f29add43b
    4e30440b394f4669a33f9b8d49ae67966325f6662bbc03a98b325a2b186adf7c
    a938701f4244ebdc4ae88ed0032a8315b68f086c6e45d9f2e34ef9442a8f6b47
    be3c749ed51ee26c8412e0304a41ac5e00e668f4d5227b5f359a3b0c31d18d5d
    2d2733a167ee360a36d6cc613001913deb62f199d73e86d39bfe06e669f4b066
    5e35263da327771ec1b9bff1d792b0da4c802f0322e40838f07554788fc191e2
    b19b23467dc33b3e8267cabea10726b0d181e0de1b491ec538b9fb620bccf57f
    6cc362dc73ea4c5094707a603f1810ddfae1a0a9937b89f44d276e2f22cad432
    1af0fbaeaf974fe3d8409854179fac68e8461524dd49849b7e889374363ce3c9
    3cfdc3c21d32cc35b1315f4ff4df87238bc7d2c27bdcf4e5a70600832c481e95
    f6364443609b1d5a07f385e7228ace0eae5040ae3bbd4e00ed5033ef1b19e4b9
    1090b7b1edba2042298b609a77bbe122982ca936208408fb79d77b33a2f3c27a
    8a4460981cabcc85054ee61881d98ad9168f7af0fc066c9adef04392a9c4b077
    3c8d7922521000b0391648ef615143b927ad7db3fb8c4cf652eedceac9ec6123)

prepare() {
    cd ${pkgname}-${pkgver}

    sed -i -e 's/GROUP="render"/GROUP="video"/' \
           -e 's/GROUP="sgx", //' rules.d/50-udev-default.rules.in
}

build() {
    cd ${pkgname}-${pkgver}

    local _timeservers=(ntp.aliyun.com ntp{1..7}.aliyun.com)

    local meson_args=(
        -Ddefault-dnssec=no
        -Dfirstboot=false
        -Dinstall-tests=false
        -Dldconfig=false
        -Dman=enabled
        -Dsysusers=true
        -Drpmmacrosdir=no
        -Dhomed=enabled
        -Duserdb=true
        -Dmode=release
        -Dpam=enabled
        -Dpamconfdir=/etc/pam.d
        -Ddev-kvm-mode=0660
        -Dnobody-group=nogroup
        -Dsysupdate=disabled
        -Dukify=enabled
        -Dlibidn2=enabled
        -Defi=true
        -Dlz4=enabled
        -Dseccomp=enabled
        -Dpcre2=enabled
        -Dpwquality=enabled
        -Dp11kit=enabled
        -Dlibcurl=enabled 
        -Dnscd=false 
        -Dselinux=disabled 
        -Ddocdir=/usr/share/doc/${pkgname}-${pkgver}
        -Dntp-servers="${_timeservers[*]}"
        -Dfallback-hostname='flarebird'
        -Dsbat-distro='Flarebird'
        -Dsbat-distro-summary="Flarebird"
        -Dsbat-distro-pkgname=${pkgname}
        -Dsbat-distro-version=${pkgver}
        -Dsbat-distro-url="https://www.futurelinux.xyz"
    )

    ${meson_options} ${meson_args[@]}

    ${meson_build}
}

package() {
    cd ${pkgname}-${pkgver}

    ${meson_install} ${pkgdir}

    install -vDm644 ${srcdir}/systemd-user ${pkgdir}/etc/pam.d/systemd-user

    chown 0:23 ${pkgdir}/var/log/journal
    chmod 2755 ${pkgdir}/var/log/journal

    rm -rf ${pkgdir}/var/log/journal/remote

    # pacman hooks
    install -vDm755 ${srcdir}/systemd-hook ${pkgdir}/usr/share/libalpm/scripts/systemd-hook
    install -vDm644 ${srcdir}/*.hook -t ${pkgdir}/usr/share/libalpm/hooks 
}