pkgname=util-linux
pkgver=2.40.2
pkgrel=1
pkgdesc="Miscellaneous system utilities for Linux"
arch=('x86_64')
url="https://git.kernel.org/pub/scm/utils/util-linux/util-linux.git/"
license=('BSD-2-Clause'
    'BSD-3-Clause'
    'BSD-4-Clause-UC'
    'GPL-2.0-only'
    'GPL-2.0-or-later'
    'GPL-3.0-or-later'
    'ISC'
    'LGPL-2.1-or-later'
    'LicenseRef-PublicDomain')
groups=('base')
depends=('coreutils' 'file' 'glibc' 'libxcrypt' 'ncurses' 'readline' 'shadow' 'zlib')
makedepends=('python' 'systemd')
source=(https://www.kernel.org/pub/linux/utils/util-linux/v${pkgver%.*}/${pkgname}-${pkgver}.tar.xz)
sha256sums=(d78b37a66f5922d70edf3bdfb01a6b33d34ed3c3cafd6628203b2a2b67c8e8b3)

build() {
    cd ${pkgname}-${pkgver}

    local configure_args=(
        --bindir=/usr/bin
        --runstatedir=/run
        --sbindir=/usr/sbin
        --disable-chfn-chsh
        --disable-login
        --disable-nologin
        --disable-su
        --disable-setpriv
        --disable-runuser
        --disable-pylibmount
        --disable-liblastlog2
        --disable-static
        --without-python
        ADJTIME_PATH=/var/lib/hwclock/adjtime
        --docdir=/usr/share/doc/${pkgname}-${pkgver}
        ${configure_options}
    )

    ./configure ${configure_args[@]}

    make
}

package() {
    cd ${pkgname}-${pkgver}

    make DESTDIR=${pkgdir} install

    install -vdm755 ${pkgdir}/var/lib/hwclock

    install -vdm755 ${pkgdir}/etc
    cat > ${pkgdir}/etc/adjtime << "EOF"
0.0 0 0.0
0
LOCAL
EOF
}