pkgname=(boost boost-libs)
pkgbase=boost
pkgver=1.87.0
pkgrel=1
pkgdesc="Free peer-reviewed portable C++ source libraries"
arch=('x86_64')
url="https://www.boost.org/"
license=('BSL-1.0')
makedepends=('icu' 'python' 'bzip2' 'zlib' 'zstd')
source=(https://github.com/boostorg/boost/releases/download/${pkgbase}-${pkgver}/${pkgbase}-${pkgver}-b2-nodocs.tar.xz)
sha256sums=(3abd7a51118a5dd74673b25e0a3f0a4ab1752d8d618f4b8cea84a603aeecc680)

build() {
    cd ${pkgname}-${pkgver}

    ./bootstrap.sh                  \
        --prefix=/usr               \
        --libdir=/usr/lib64         \
        --with-python=python3       \
        --with-icu                  \
        --with-toolset=gcc          \
        --with-python-version="$(python3 -c 'import sys; print(".".join(map(str, sys.version_info[:2])))')"

    ./b2 stage ${MAKEFLAGS} threading=multi link=shared runtime-link=shared toolset=gcc --cxxflags="${CXXFLAGS} ${LDFLAGS}"

}

package_boost() {
    pkgdesc+=' (development headers)'
    depends=("boost-libs=${pkgver}")

    cd ${pkgname}-${pkgver}


    ./b2 install                \
         toolset=gcc            \
         threading=multi        \
         link=shared            \
         runtime-link=shared    \
         cflags="${CPPFLAGS} ${CFLAGS} -fPIC -O3 -ffat-lto-objects"     \
         cxxflags="${CPPFLAGS} ${CXXFLAGS} -fPIC -O3 -ffat-lto-objects" \
         linkflags="${LDFLAGS}" \
         --prefix=${pkgdir}/usr \
         --libdir=${pkgdir}/usr/lib64

    _pick boost-libs ${pkgdir}/usr/lib64/*.so*
}

package_boost-libs() {
    pkgdesc+=' (runtime libraries)'
    depends=('bzip2' 'zlib' 'icu' 'zstd' 'which')

    mv ${pkgname}/* ${pkgdir}
}