pkgname=expect
pkgver=5.45.4
pkgrel=1
pkgdesc="A tool for automating interactive applications"
arch=('x86_64')
url="https://www.nist.gov/el/msid/expect.cfm"
license=('Public-Domain')
depends=('tcl')
source=(https://prdownloads.sourceforge.net/${pkgname}/${pkgname}${pkgver}.tar.gz
    https://www.linuxfromscratch.org/patches/downloads/${pkgname}/${pkgname}-${pkgver}-gcc14-1.patch
    expect-5.45-format-security.patch)
sha256sums=(49a7da83b0bdd9f46d04a04deec19c7767bb9a323e40c4781f89caf760b92c34
    517c0cdd5db949cdd99dfa38b7a6c3945e1524c50e3467028973298f2c76a92c
    ef8bcc479d6ebd5374e601e89a56dbc4ab7928ee2a4615a98b29e9a8e687b5a4)

prepare() {
    cd ${pkgname}${pkgver}

    patch -Np1 -i ${srcdir}/${pkgname}-${pkgver}-gcc14-1.patch
    patch -Np0 -i ${srcdir}/expect-5.45-format-security.patch
}

build() {
    cd ${pkgname}${pkgver}

    local configure_args=(
        --with-tcl=/usr/lib64
        --enable-shared
        --disable-rpath
        --mandir=/usr/share/man
        --with-tclinclude=/usr/include
        ${configure_options}
    )

    ./configure ${configure_args[@]}

    make
}

package() {
    cd ${pkgname}${pkgver}

    make DESTDIR=${pkgdir} install

    ln -svf expect${pkgver}/libexpect${pkgver}.so ${pkgdir}/usr/lib64
}