pkgname=fuse
pkgver=3.16.2
pkgrel=1
pkgdesc="Interface for userspace programs to export a filesystem to the Linux kernel"
arch=('x86_64')
url="https://github.com/libfuse/libfuse"
license=('GPL-2.0-only' 'LGPL-2.1-only')
depends=('glibc')
makedepends=('pkgconf' 'meson')
backup=(etc/fuse.conf)
options=('!emptydirs')
source=(https://github.com/libfuse/libfuse/releases/download/${pkgname}-${pkgver}/${pkgname}-${pkgver}.tar.gz)
sha256sums=(f797055d9296b275e981f5f62d4e32e089614fc253d1ef2985851025b8a0ce87)

prepare() {
    cd ${pkgname}-${pkgver}

    sed -i '/^udev/,$ s/^/#/' util/meson.build
}

build() {
    cd ${pkgname}-${pkgver}

    local meson_args=(
    )

    ${meson_options} ${meson_args[@]}

    ${meson_build}
}

package() {
    cd ${pkgname}-${pkgver}

    ${meson_install} ${pkgdir}

    chmod u+s ${pkgdir}/usr/bin/fusermount3

    install -vdm755 ${pkgdir}/usr/share/doc/fuse-${pkgver}
    cp -Rv doc/html -T ${pkgdir}/usr/share/doc/fuse-${pkgver}
    install -v -m644   doc/{README.NFS,kernel.txt} ${pkgdir}/usr/share/doc/fuse-${pkgver}

    install -vdm755 ${pkgdir}/etc
    cat > ${pkgdir}/etc/fuse.conf << "EOF"
# Set the maximum number of FUSE mounts allowed to non-root users.
# The default is 1000.
#
#mount_max = 1000

# Allow non-root users to specify the 'allow_other' or 'allow_root'
# mount options.
#
#user_allow_other
EOF
}