pkgname=libcupsfilters
pkgver=2.1.0
pkgrel=1
pkgdesc="OpenPrinting CUPS Filters - contains all the code of the filters of the former cups-filters package as library functions"
arch=('x86_64')
url="https://github.com/OpenPrinting/libcupsfilters"
license=('Apache-2.0 WITH LLVM-exception')
depends=(
    'dbus'
    'fontconfig'
    'gcc-libs'
    'glibc'
    'lcms2'
    'libcups'
    'libexif'
    'libjpeg-turbo'
    'libpng'
    'libtiff'
    'poppler'
    'qpdf'
)
makedepends=('ghostscript' 'mupdf')
source=(https://github.com/OpenPrinting/libcupsfilters/releases/download/${pkgver}/${pkgname}-${pkgver}.tar.xz)
sha256sums=(cbe900c7783e4aab0b1681629fad7322d82d082a51e8bae7e1c741d26bdcd294)

build() {
    cd ${pkgname}-${pkgver}

    local configure_args=(
        --disable-static
        --docdir=/usr/share/doc/${pkgname}-${pkgver}
        ${configure_options}
    )

    ./configure ${configure_args[@]}

    make
}

package() {
    cd ${pkgname}-${pkgver}

    make DESTDIR=${pkgdir} install
}