pkgname=libpng
pkgver=1.6.44
pkgrel=1
pkgdesc="A collection of routines used to create PNG format graphics files"
arch=('x86_64')
url="http://www.libpng.org/pub/png/libpng.html"
license=('custom')
depends=('zlib' 'bash')
source=(https://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.xz
    https://downloads.sourceforge.net/sourceforge/${pkgname}-apng/${pkgname}-${pkgver}-apng.patch.gz)
sha256sums=(60c4da1d5b7f0aa8d158da48e8f8afa9773c1c8baa5d21974df61f1886b8ce8e
    17d2e51f2bc93f4a22070b35fddd3655a4ec1a90ba8b7db2bffde7afc8d76dd3)

prepare() {
    cd ${pkgname}-${pkgver}

    gzip -cd ${srcdir}/${pkgname}-${pkgver}-apng.patch.gz | patch -p1
}

build() {
    cd ${pkgname}-${pkgver}

    local configure_args=(
        --disable-static
        ${configure_options}
    )

    ./configure ${configure_args[@]}

    make
}

package() {
    cd ${pkgname}-${pkgver}

    make DESTDIR=${pkgdir} install

    install -vdm755 ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
    cp -v README libpng-manual.txt ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
}