pkgname=lm-sensors
pkgver=3.6.0
pkgrel=1
pkgdesc="Collection of user space tools for general SMBus access and hardware monitoring"
arch=('x86_64')
url="https://hwmon.wiki.kernel.org/lm_sensors"
license=('GPL' 'LGPL')
depends=('bash' 'glibc' 'which')
makedepends=('perl')
backup=(etc/sensors3.conf)
source=(https://github.com/lm-sensors/lm-sensors/archive/V${pkgver//./-}/${pkgname}-${pkgver//./-}.tar.gz)
sha256sums=(0591f9fa0339f0d15e75326d0365871c2d4e2ed8aa1ff759b3a55d3734b7d197)

build() {
    cd ${pkgname}-${pkgver//./-}

    make CC=${CHOST}-gcc       \
         CXX=${CHOST}-g++      \
         PREFIX=/usr           \
         LIBDIR=/usr/lib64     \
         BUILD_STATIC_LIB=0    \
         MANDIR=/usr/share/man \
         EXLDFLAGS=
}

package() {
    cd ${pkgname}-${pkgver//./-}

    make PREFIX=/usr           \
         LIBDIR=/usr/lib64     \
         BUILD_STATIC_LIB=0    \
         MANDIR=/usr/share/man \
         DESTDIR=${pkgdir} install

    install -v -m755 -d ${pkgdir}/usr/share/doc/${pkgname}-${pkgver//./-}
    cp -rv              README INSTALL doc/* ${pkgdir}/usr/share/doc/${pkgname}-${pkgver//./-}
}