pkgname=poppler
pkgver=25.01.0
pkgrel=1
pkgdesc="PDF rendering library based on xpdf 3.0"
arch=('x86_64')
url="https://poppler.freedesktop.org/"
license=(
    'GPL-2.0-only'
    'GPL-3.0-or-later'
    'LGPL-2.0-or-later'
    'LGPL-2.1-or-later'
    'MIT'
    'HPND-sell-variant'
)
depends=(
    'cairo'
    'curl'
    'fontconfig'
    'freetype2'
    'gcc-libs'
    'glibc'
    'gpgme'
    'lcms2'
    'libjpeg-turbo'
    'libpng'
    'libtiff'
    'nspr'
    'nss'
    'openjpeg'
    'zlib'
)
makedepends=('boost' 'cmake' 'poppler-data')
options=('!emptydirs')
source=(https://poppler.freedesktop.org/${pkgname}-${pkgver}.tar.xz)
sha256sums=(7eefc122207bbbd72a303c5e0743f4941e8ae861e24dcf0501e18ce1d1414112)

build() {
    cd ${pkgname}-${pkgver}

    local cmake_args=(
        -B flarebird-build
        -DCMAKE_BUILD_TYPE=Release
        -DCMAKE_INSTALL_PREFIX=/usr
        -DCMAKE_INSTALL_LIBDIR=lib64
        -DTESTDATADIR=${PWD}/testfiles
        -DENABLE_QT5=OFF
        -DENABLE_QT6=OFF
        -DENABLE_UNSTABLE_API_ABI_HEADERS=ON
    )

    cmake ${cmake_args[@]}

    cmake --build flarebird-build
}

package() {
    cd ${pkgname}-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build

    install -vdm755 ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
    cp -vr glib/reference/html ${pkgdir}/usr/share/doc/${pkgname}-${pkgver}
}