pkgname=rsync
pkgver=3.3.0
pkgrel=1
pkgdesc="A fast and versatile file copying tool for remote and local files"
arch=('x86_64')
url="https://rsync.samba.org"
license=('GPL-3.0-or-later')
depends=('acl' 'attr' 'lz4' 'openssl' 'popt' 'zlib' 'zstd')
backup=(etc/rsyncd.conf)
install=${pkgname}.install
source=(https://www.samba.org/ftp/rsync/src/${pkgname}-${pkgver}.tar.gz
    rsyncdat.service
    rsyncd.service
    rsyncd.socket)
sha256sums=(7399e9a6708c32d678a72a63219e96f23be0be2336e50fd1348498d07041df90
    6822d0a0b11fcbe9c328f06ba93784fb5454d453e88d7a400d3c08e69a0ad5b4
    f9e576be233f11c6d6320c5b03624c7b7d377f9242194cfae2d571a036b8e764
    551f17407de0e539c8419fc2cd48dd0124eb0253a186690b165b51703ffad1a5)

build() {
    cd ${pkgname}-${pkgver}

    local configure_args=(
        --disable-xxhash
        --enable-openssl
        --enable-zstd
        --enable-lz4
        --enable-acl-support
        --enable-xattr-support
        --without-included-popt
        --without-included-zlib
        ${configure_options}
    )

    ./configure ${configure_args[@]}

    make
}

package() {
    cd ${pkgname}-${pkgver}

    make DESTDIR=${pkgdir} install

    install -vdm755 ${pkgdir}/etc
    cat > ${pkgdir}/etc/rsyncd.conf << "EOF"
# This is a basic rsync configuration file
# It exports a single module without user authentication.

motd file = /srv/rsync/welcome.msg
use chroot = yes

[localhost]
    path = /srv/rsync
    comment = Default rsync module
    read only = yes
    list = yes
    uid = rsyncd
    gid = rsyncd

EOF

    install -vDm644 ${srcdir}/rsyncd.service ${pkgdir}/usr/lib/systemd/system/rsyncd.service
    install -vDm644 ${srcdir}/rsyncdat.service ${pkgdir}/usr/lib/systemd/system/rsyncd@.service
    install -vDm644 ${srcdir}/rsyncd.socket ${pkgdir}/usr/lib/systemd/system/rsyncd.socket
}