pkgname=drkonqi
pkgver=6.0.4
pkgrel=1
pkgdesc="The KDE crash handler"
arch=('x86_64')
url="https://kde.org/plasma-desktop"
license=('LGPL-2.0-or-later')
groups=('plasma')
depends=('gcc-libs' 'gdb' 'glibc' 'kcmutils' 'kconfig' 'kcoreaddons' 'kcrash' 'ki18n'
    'kidletime' 'kio' 'kirigami' 'kitemmodels' 'knotifications' 'kservice'
    'kstatusnotifieritem' 'kwallet' 'kwidgetsaddons' 'kwindowsystem' 'polkit-qt'
    'python' 'python-psutil' 'python-pygdbmi' 'python-sentry_sdk' 'qt6-qtbase'
    'qt6-qtdeclarative' 'syntax-highlighting' 'systemd')
makedepends=('extra-cmake-modules' 'cmake')
source=(https://download.kde.org/stable/plasma/${pkgver}/${pkgname}-${pkgver}.tar.xz)
sha256sums=(e0ee7aeebcc518808d4e27f19afe959eecef2d54a6d0c876de74b19365ec3710)

build() {
    cd ${pkgname}-${pkgver}

    cmake -B flarebird-build -Wno-dev                   \
          -DCMAKE_INSTALL_PREFIX=/usr         \
          -DCMAKE_INSTALL_LIBEXECDIR=libexec  \
          -DKDE_INSTALL_LIBDIR=lib64          \
          -DCMAKE_BUILD_TYPE=Release          \
          -DBUILD_QT5=OFF                     \
          -DBUILD_TESTING=OFF                 \
          -DWITH_GDB12=ON                     \
          -DWITH_PYTHON_VENDORING=OFF

    cmake --build flarebird-build
}

package() {
    cd ${pkgname}-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build
}