pkgname=kde-gtk-config
pkgver=6.0.4
pkgrel=1
pkgdesc="Syncs KDE settings to GTK applications"
arch=('x86_64')
url="https://kde.org/plasma-desktop"
license=('LGPL-2.0-or-later')
groups=('plasma')
depends=('gcc-libs' 'glib2' 'glibc' 'kcolorscheme' 'kconfig' 'kcoreaddons' 'kdbusaddons'
    'kdecoration' 'kguiaddons' 'kwindowsystem' 'qt6-qtbase' 'qt6-qtsvg' 'bash' 'xsettingsd'
    'gsettings-desktop-schemas')
makedepends=('extra-cmake-modules' 'cmake' 'gtk3' 'sassc')
source=(https://download.kde.org/stable/plasma/${pkgver}/${pkgname}-${pkgver}.tar.xz)
sha256sums=(fd5491c2b0e887dc204e1661ac7f364f2c0965085ce4f50fa22857e0ed285dbd)

build() {
    cd ${pkgname}-${pkgver}

    cmake -B flarebird-build -Wno-dev                   \
          -DCMAKE_INSTALL_PREFIX=/usr         \
          -DCMAKE_INSTALL_LIBEXECDIR=libexec  \
          -DKDE_INSTALL_LIBDIR=lib64          \
          -DCMAKE_BUILD_TYPE=Release          \
          -DBUILD_QT5=OFF                     \
          -DBUILD_TESTING=OFF

    cmake --build flarebird-build
}

package() {
    cd ${pkgname}-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build
}