pkgname=kinfocenter
pkgver=6.0.4
pkgrel=2
pkgdesc="A utility that provides information about a computer system"
arch=('x86_64')
url="https://kde.org/plasma-desktop"
license=('LGPL-2.0-or-later')
groups=('plasma')
depends=('gcc-libs' 'glibc' 'glu' 'kauth' 'kcmutils' 'kconfig' 'kcoreaddons' 'kdeclarative'
    'ki18n' 'kio' 'kirigami' 'kservice' 'kwidgetsaddons' 'libusb' 'mesa' 'qt6-qtbase'
    'qt6-qtdeclarative' 'bash' 'solid' 'xdpyinfo' 'vulkan-tools' 'systemsettings' 'wayland-utils')
makedepends=('extra-cmake-modules' 'cmake' 'ninja' 'kdoctools' 'docbook-xml' 'docbook-xsl')
source=(https://download.kde.org/stable/plasma/${pkgver}/${pkgname}-${pkgver}.tar.xz)
sha256sums=(5af1ab7fd5c54f95221537bd4ee913dfa067ddff3a1cb4b5d486de539a48268e)

build() {
    cd ${pkgname}-${pkgver}

    cmake -G Ninja -B flarebird-build                   \
          -DCMAKE_INSTALL_PREFIX=/usr         \
          -DCMAKE_INSTALL_LIBEXECDIR=libexec  \
          -DKDE_INSTALL_LIBDIR=lib64          \
          -DCMAKE_BUILD_TYPE=Release          \
          -DBUILD_QT5=OFF                     \
          -DBUILD_TESTING=OFF                 \
          -Wno-dev

    cmake --build flarebird-build
}

package() {
    cd ${pkgname}-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build
}