pkgname=kpipewire
pkgver=6.0.4
pkgrel=1
pkgdesc="Components relating to pipewire use in Plasma"
arch=('x86_64')
url="https://kde.org/plasma-desktop"
license=('LGPL-2.0-or-later')
groups=('plasma')
depends=('ffmpeg' 'gcc-libs' 'glibc' 'kcoreaddons' 'ki18n' 'libdrm' 'libepoxy'
    'pipewire' 'libva' 'mesa' 'qt6-qtbase' 'qt6-qtdeclarative')
makedepends=('extra-cmake-modules' 'cmake' 'ninja' 'plasma-wayland-protocols')
source=(https://download.kde.org/stable/plasma/${pkgver}/${pkgname}-${pkgver}.tar.xz)
sha256sums=(a17442fb4f719f154de10158b9da0791a9a4b7da2d0b6f82303fb3b7a2f46836)

build() {
    cd ${pkgname}-${pkgver}

    cmake -G Ninja -B flarebird-build                   \
          -DCMAKE_INSTALL_PREFIX=/usr         \
          -DCMAKE_INSTALL_LIBEXECDIR=libexec  \
          -DKDE_INSTALL_LIBDIR=lib64          \
          -DCMAKE_BUILD_TYPE=Release          \
          -DBUILD_QT5=OFF                     \
          -DBUILD_TESTING=OFF                 \
          -Wno-dev

    cmake --build flarebird-build
}

package() {
    cd ${pkgname}-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build
}