pkgname=kscreenlocker
pkgver=6.0.4
pkgrel=1
pkgdesc="Library and components for secure lock screen architecture"
arch=('x86_64')
url="https://kde.org/plasma-desktop"
license=('LGPL-2.0-or-later')
groups=('plasma')
depends=('gcc-libs' 'glibc' 'kconfig' 'kcoreaddons' 'kcrash' 'kdeclarative' 'kglobalaccel' 'ki18n'
    'kidletime' 'kio' 'kirigami' 'knotifications' 'kpackage' 'ksvg' 'kwindowsystem' 'kxmlgui'
    'layer-shell-qt' 'libkscreen' 'libx11' 'libxcb' 'libxi' 'linux-pam' 'libplasma' 'qt6-qtbase'
    'qt6-qtdeclarative' 'wayland' 'xcb-util-keysyms')
makedepends=('extra-cmake-modules' 'cmake' 'ninja' 'kcmutils' 'kdoctools')
backup=(etc/pam.d/kde-np
    etc/pam.d/kde
    etc/pam.d/kscreensaver)
source=(https://download.kde.org/stable/plasma/${pkgver}/${pkgname}-${pkgver}.tar.xz
    kde-np.pam
    kde.pam
    kscreensaver.pam)
sha256sums=(3c18a86d260df081dc2cbcebaa2c5c851a9c957719c5e12d43004fc7c32debd5
    aa8b85bf05000d419b60a5f03e110b5a4e350cabeeeabb047a91167fbdaba7bc  
    135bef508b4ca0e03e090202d2cc45e4d07a9070ece7b01a170d3387deeabe5b
    b0294abd2389977365c24df76ea0df94525ff61f583f97f124f314e068077cee)

build() {
    cd ${pkgname}-${pkgver}

    cmake -G Ninja -B flarebird-build                   \
          -DCMAKE_INSTALL_PREFIX=/usr         \
          -DCMAKE_INSTALL_LIBEXECDIR=libexec  \
          -DKDE_INSTALL_LIBDIR=lib64          \
          -DCMAKE_BUILD_TYPE=Release          \
          -DBUILD_QT5=OFF                     \
          -DBUILD_TESTING=OFF                 \
          -Wno-dev

    cmake --build flarebird-build
}

package() {
    cd ${pkgname}-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build

    install -Dm644 ${srcdir}/kde-np.pam ${pkgdir}/etc/pam.d/kde-np
    install -Dm644 ${srcdir}/kde.pam ${pkgdir}/etc/pam.d/kde
    install -Dm644 ${srcdir}/kscreensaver.pam ${pkgdir}/etc/pam.d/kscreensaver
}