pkgname=kwin
pkgver=6.0.4.1
pkgrel=1
pkgdesc="An easy to use, but flexible, composited Window Manager"
arch=('x86_64')
url="https://kde.org/plasma-desktop"
license=('LGPL-2.0-or-later')
groups=('plasma')
depends=('breeze' 'gcc-libs' 'glibc' 'plasma-activities' 'kauth' 'kcmutils' 'kcolorscheme' 'kconfig'
    'kconfigwidgets' 'kcoreaddons' 'kcrash' 'kdbusaddons' 'kdeclarative' 'kdecoration' 'kglobalaccel'
    'kglobalacceld' 'kguiaddons' 'ki18n' 'kidletime' 'kirigami' 'kitemmodels' 'knewstuff' 'knotifications'
    'kpackage' 'kquickcharts' 'kscreenlocker' 'kservice' 'ksvg' 'kwayland' 'kwidgetsaddons'
    'kwindowsystem' 'kxmlgui' 'lcms2' 'libdisplay-info' 'libdrm' 'libepoxy' 'libinput' 'pipewire'
    'libx11' 'libxcb' 'libxcvt' 'libxi' 'libxkbcommon' 'mesa' 'pipewire-session-manager' 'libplasma'
    'qt6-qt5compat' 'qt6-qtbase' 'qt6-qtdeclarative' 'qt6-qtmultimedia' 'qt6-qtsensors' 'qt6-qttools'
    'qt6-qtwayland' 'systemd' 'wayland' 'xcb-util-cursor' 'xcb-util-keysyms' 'xcb-util-wm')
makedepends=('extra-cmake-modules' 'cmake' 'ninja' 'kdoctools' 'krunner'
    'plasma-wayland-protocols' 'python' 'wayland-protocols' 'xwayland')
source=(https://download.kde.org/stable/plasma/${pkgver%.*}/${pkgname}-${pkgver}.tar.xz)
sha256sums=(56ffb37fa36e10f058ec5499c6858f6b21105b56ac7d70407921f063bc4bcb36)

build() {
    cd ${pkgname}-${pkgver}

    cmake -G Ninja -B flarebird-build                   \
          -DCMAKE_INSTALL_PREFIX=/usr         \
          -DCMAKE_INSTALL_LIBEXECDIR=libexec  \
          -DKDE_INSTALL_LIBDIR=lib64          \
          -DCMAKE_BUILD_TYPE=Release          \
          -DBUILD_QT5=OFF                     \
          -DBUILD_TESTING=OFF                 \
          -Wno-dev

    cmake --build flarebird-build
}

package() {
    cd ${pkgname}-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build
}