pkgname=libksysguard
pkgver=6.0.4
pkgrel=1
pkgdesc="Library to retrieve information on the current status of computer hardware"
arch=('x86_64')
url="https://kde.org/plasma-desktop"
license=('LGPL-2.0-or-later')
groups=('plasma')
depends=('gcc-libs' 'glibc' 'kauth' 'kconfig' 'kcoreaddons' 'kdeclarative' 'ki18n' 'kirigami' 'kitemmodels'
    'knewstuff' 'kpackage' 'kquickcharts' 'kservice' 'libnl' 'libpcap' 'qt6-qtbase'
    'qt6-qtdeclarative' 'solid' 'zlib' 'lm_sensors')
makedepends=('extra-cmake-modules' 'cmake' 'ninja' 'qt6-qttools')
install=${pkgname}.install
source=(https://download.kde.org/stable/plasma/${pkgver}/${pkgname}-${pkgver}.tar.xz)
sha256sums=(566ac2f0603012892b2291aa6d4663b06ea654c3db366f65a59e32503bfa8dea)

build() {
    cd ${pkgname}-${pkgver}

    cmake -G Ninja -B flarebird-build                   \
          -DCMAKE_INSTALL_PREFIX=/usr         \
          -DCMAKE_INSTALL_LIBEXECDIR=libexec  \
          -DKDE_INSTALL_LIBDIR=lib64          \
          -DCMAKE_BUILD_TYPE=Release          \
          -DBUILD_QT5=OFF                     \
          -DBUILD_TESTING=OFF                 \
          -Wno-dev

    cmake --build flarebird-build
}

package() {
    cd ${pkgname}-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build
}