pkgname=(oxygen-icons oxygen-icons-svg)
pkgbase=oxygen-icons
pkgver=6.0.0
pkgrel=1
pkgdesc="The Oxygen Icon Theme"
arch=('x86_64')
url="https://community.kde.org/Frameworks"
license=('LGPL-2.1-or-later')
makedepends=('extra-cmake-modules' 'cmake' 'qt6-qtbase')
source=(https://download.kde.org/stable/${pkgbase}/${pkgbase}-${pkgver}.tar.xz)
sha256sums=(28ec182875dcc15d9278f45ced11026aa392476f1f454871b9e2c837008e5774)

prepare() {
    cd ${pkgbase}-${pkgver}

    sed -i '/( oxygen/ s/)/scalable )/' CMakeLists.txt
}

build() {
    cd ${pkgbase}-${pkgver}

    cmake -B flarebird-build -Wno-dev           \
          -DCMAKE_INSTALL_PREFIX=/usr \
          -DCMAKE_BUILD_TYPE=Release
          

    cmake --build flarebird-build
}

package_oxygen-icons() {
    cd ${pkgbase}-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build
}

package_oxygen-icons-svg() {
    pkgdesc='The Oxygen Icon Theme (Scalable Vector Graphics)'

    cd ${pkgbase}-${pkgver}

    find scalable -type f ! -name '*.sh' -exec install -D -m644 "{}" ${pkgdir}/usr/share/icons/oxygen/{} \;
}