pkgname=plasma-pa
pkgver=6.0.4
pkgrel=1
pkgdesc="Plasma applet for audio volume management using PulseAudio"
arch=('x86_64')
url="https://kde.org/plasma-desktop"
license=('LGPL-2.0-or-later')
groups=('plasma')
depends=('gcc-libs' 'glib2' 'glibc' 'kcmutils' 'kconfig' 'kcoreaddons' 'kdeclarative'
    'kglobalaccel' 'ki18n' 'kirigami' 'kitemmodels' 'kstatusnotifieritem' 'ksvg'
    'libcanberra' 'libplasma' 'pulseaudio' 'plasma-workspace' 'pipewire'
    'qt6-qtbase' 'qt6-qtdeclarative')
makedepends=('extra-cmake-modules' 'cmake' 'kdoctools')
source=(https://download.kde.org/stable/plasma/${pkgver}/${pkgname}-${pkgver}.tar.xz)
sha256sums=(329ad1c326798459beab145eced43e6ee962378d95299c1a64f5a929eabda601)

build() {
    cd ${pkgname}-${pkgver}

    cmake -B flarebird-build -Wno-dev                   \
          -DCMAKE_INSTALL_PREFIX=/usr         \
          -DCMAKE_INSTALL_LIBEXECDIR=libexec  \
          -DKDE_INSTALL_LIBDIR=lib64          \
          -DCMAKE_BUILD_TYPE=Release          \
          -DBUILD_QT5=OFF                     \
          -DBUILD_TESTING=OFF

    cmake --build flarebird-build
}

package() {
    cd ${pkgname}-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build
}