pkgname=plasma-welcome
pkgver=6.0.4
pkgrel=1
pkgdesc="A friendly onboarding wizard for Plasma"
arch=('x86_64')
url="https://kde.org/plasma-desktop"
license=('LGPL-2.0-or-later')
groups=('plasma')
depends=('gcc-libs' 'glibc' 'kcmutils' 'kconfig' 'kcoreaddons' 'kdbusaddons'
    'ki18n' 'kio' 'kirigami' 'kirigami-addons' 'kjobwidgets' 'knewstuff'
    'kservice' 'kuserfeedback' 'kwindowsystem' 'plasma-nm' 'qt6-qt5compat'
    'qt6-qtbase' 'qt6-qtdeclarative')
makedepends=('extra-cmake-modules' 'cmake')
source=(https://download.kde.org/stable/plasma/${pkgver}/${pkgname}-${pkgver}.tar.xz)
sha256sums=(6bca8749d75cba353e45842e6287d1922dcd18ced4b8ad386858570bbe9c1852)

build() {
    cd ${pkgname}-${pkgver}

    cmake -B flarebird-build -Wno-dev                   \
          -DCMAKE_INSTALL_PREFIX=/usr         \
          -DCMAKE_INSTALL_LIBEXECDIR=libexec  \
          -DKDE_INSTALL_LIBDIR=lib64          \
          -DCMAKE_BUILD_TYPE=Release          \
          -DBUILD_QT5=OFF                     \
          -DBUILD_TESTING=OFF

    cmake --build flarebird-build
}

package() {
    cd ${pkgname}-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build
}