pkgname=polkit-kde-agent
pkgver=6.0.4
pkgrel=1
pkgdesc="Daemon providing a polkit authentication UI for KDE"
arch=('x86_64')
url="https://kde.org/plasma-desktop"
license=('LGPL-2.0-or-later')
groups=('plasma')
depends=('gcc-libs' 'glibc' 'kcoreaddons' 'kcrash' 'kdbusaddons' 'ki18n' 'kirigami'
    'kwindowsystem' 'polkit-qt' 'qt6-qt5compat' 'qt6-qtbase' 'qt6-qtdeclarative')
makedepends=('extra-cmake-modules' 'cmake' 'kdoctools')
source=(https://download.kde.org/stable/plasma/${pkgver}/${pkgname}-1-${pkgver}.tar.xz)
sha256sums=(e0fcbb8a1cfab8be69b2713b2105b0235137381f1fdb6d465c3978e6b8626b24)

build() {
    cd ${pkgname}-1-${pkgver}

    cmake -B flarebird-build -Wno-dev                   \
          -DCMAKE_INSTALL_PREFIX=/usr         \
          -DCMAKE_INSTALL_LIBEXECDIR=libexec  \
          -DKDE_INSTALL_LIBDIR=lib64          \
          -DCMAKE_BUILD_TYPE=Release          \
          -DBUILD_QT5=OFF                     \
          -DBUILD_TESTING=OFF

    cmake --build flarebird-build
}

package() {
    cd ${pkgname}-1-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build
}