pkgname=print-manager
pkgver=6.0.4
pkgrel=1
pkgdesc="A tool for managing print jobs and printers"
arch=('x86_64')
url="https://kde.org/plasma-desktop"
license=('LGPL-2.0-or-later')
groups=('plasma')
depends=('gcc-libs' 'glibc' 'kcmutils' 'kconfig' 'kcoreaddons' 'kdbusaddons' 'ki18n'
    'kiconthemes' 'kio' 'kirigami' 'knotifications' 'kwidgetsaddons' 'kwindowsystem'
    'libcups' 'libplasma' 'qt6-qt5compat' 'qt6-qtbase' 'qt6-qtdeclarative')
makedepends=('extra-cmake-modules' 'cmake' 'kdoctools')
source=(https://download.kde.org/stable/plasma/${pkgver}/${pkgname}-${pkgver}.tar.xz)
sha256sums=(40926cacb65c90c49dd4758f57b606ba571f49ea66ff42c031c69fdbe7221c08)

build() {
    cd ${pkgname}-${pkgver}

    cmake -B flarebird-build -Wno-dev                   \
          -DCMAKE_INSTALL_PREFIX=/usr         \
          -DCMAKE_INSTALL_LIBEXECDIR=libexec  \
          -DKDE_INSTALL_LIBDIR=lib64          \
          -DCMAKE_BUILD_TYPE=Release          \
          -DBUILD_QT5=OFF                     \
          -DBUILD_TESTING=OFF

    cmake --build flarebird-build
}

package() {
    cd ${pkgname}-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build
}