pkgname=sddm
pkgver=0.21.0
pkgrel=4
pkgdesc="QML based X11 and Wayland display manager"
arch=('x86_64')
url="https://github.com/sddm/sddm"
license=('GPL-2.0-only')
depends=('bash' 'gcc-libs' 'glibc' 'libxau' 'libxcb' 'linux-pam' 'qt6-qtbase'
    'qt6-qtdeclarative' 'systemd' 'dejavu-fonts' 'xorg-server' 'xauth'
    'noto-fonts' 'googlefonts-croscore-fonts' 'fonts-ttf-bitstream-vera'
    'fonts-gnu-free' 'googlefonts-croscore-fonts' 'fonts-ttf-mona-sans'
    'fonts-ttf-input' 'fonts-ttf-droid' 'fonts-ttf-liberation')
makedepends=('extra-cmake-modules' 'cmake' 'python-docutils' 'qt6-qttools')
backup=(etc/sddm.conf
    etc/pam.d/sddm
    etc/pam.d/sddm-autologin
    etc/pam.d/sddm-greeter)
install=${pkgname}.install
source=(https://github.com/sddm/sddm/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz
    sddm-autologin.pam
    sddm-greeter.pam
    sddm.pam)
sha256sums=(f895de2683627e969e4849dbfbbb2b500787481ca5ba0de6d6dfdae5f1549abf
    8112392b9d74d2bf2a3a623f7bfcd90c6e631cb2adc299a3be2acb5ca40e438b  
    be6239ceef2354e19d68141d56024cfab10eeb916861e61f062f142c0a6d773d
    30b3ab169efd1a6781afc187e4d46f64b8e0f16a0655c42ad62137b6e526545c)

build() {
    cd ${pkgname}-${pkgver}

    cmake -B flarebird-build  -Wno-dev                 \
          -DCMAKE_INSTALL_PREFIX=/usr        \
          -DCMAKE_BUILD_TYPE=Release         \
          -DRUNTIME_DIR=/run/sddm            \
          -DBUILD_MAN_PAGES=ON               \
          -DBUILD_WITH_QT6=ON                \
          -DUID_MAX=60513                    \
          -DDATA_INSTALL_DIR=/usr/share/sddm \
          -DDBUS_CONFIG_FILENAME=sddm_org.freedesktop.DisplayManager.conf

    cmake --build flarebird-build
}

package() {
    cd ${pkgname}-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build

    install -v -dm755 -o 64  -g 64  ${pkgdir}/var/lib/sddm
    ${pkgdir}/usr/bin/sddm --example-config > ${pkgdir}/etc/sddm.conf

    sed -i 's/-nolisten tcp//' ${pkgdir}/etc/sddm.conf
    sed -i '/Numlock/s/none/on/' ${pkgdir}/etc/sddm.conf
    sed -i 's/qtvirtualkeyboard//' ${pkgdir}/etc/sddm.conf

    install -vDm644 ${srcdir}/sddm-autologin.pam ${pkgdir}/etc/pam.d/sddm-autologin
    install -vDm644 ${srcdir}/sddm-greeter.pam   ${pkgdir}/etc/pam.d/sddm-greeter
    install -vDm644 ${srcdir}/sddm.pam           ${pkgdir}/etc/pam.d/sddm
}