pkgname=systemsettings
pkgver=6.0.4
pkgrel=1
pkgdesc="KDE system manager for hardware, software, and workspaces"
arch=('x86_64')
url="https://kde.org/plasma-desktop"
license=('LGPL-2.0-or-later')
groups=('plasma')
depends=('gcc-libs' 'glibc' 'plasma-activities' 'kauth' 'kcmutils' 'kcolorscheme'
    'kconfig' 'kconfigwidgets' 'kcoreaddons' 'kcrash' 'kdbusaddons' 'ki18n'
    'kiconthemes' 'kio' 'kirigami' 'kitemmodels' 'kitemviews' 'kjobwidgets'
    'krunner' 'kservice' 'kwidgetsaddons' 'kwindowsystem' 'kxmlgui' 'qt6-qtbase'
    'qt6-qtdeclarative')
makedepends=('extra-cmake-modules' 'cmake' 'kdoctools' 'docbook-xml' 'docbook-xsl')
source=(https://download.kde.org/stable/plasma/${pkgver}/${pkgname}-${pkgver}.tar.xz)
sha256sums=(18c8016230083d8f2ec98d33c0157756060c5a136e8995769dbf7ef326c402ed)

build() {
    cd ${pkgname}-${pkgver}

    cmake -B flarebird-build -Wno-dev                   \
          -DCMAKE_INSTALL_PREFIX=/usr         \
          -DCMAKE_INSTALL_LIBEXECDIR=libexec  \
          -DKDE_INSTALL_LIBDIR=lib64          \
          -DCMAKE_BUILD_TYPE=Release          \
          -DBUILD_QT5=OFF                     \
          -DBUILD_TESTING=OFF

    cmake --build flarebird-build
}

package() {
    cd ${pkgname}-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build
}