pkgname=xdg-desktop-portal-kde
pkgver=6.0.4
pkgrel=1
pkgdesc="A backend implementation for xdg-desktop-portal using Qt/KF6"
arch=('x86_64')
url="https://kde.org/plasma-desktop"
license=('LGPL-2.0-or-later')
groups=('plasma')
depends=('gcc-libs' 'glibc' 'kconfig' 'kcoreaddons' 'kglobalaccel' 'kiconthemes'
    'ki18n' 'kio' 'kio-fuse' 'kirigami' 'kitemviews' 'knotifications' 'kpipewire'
    'kservice' 'kstatusnotifieritem' 'kwayland' 'kwindowsystem' 'libxkbcommon'
    'plasma-workspace' 'qt6-qtbase' 'qt6-qtdeclarative' 'wayland' 'xdg-desktop-portal')
makedepends=('extra-cmake-modules' 'cmake' 'plasma-wayland-protocols' 'wayland-protocols')
source=(https://download.kde.org/stable/plasma/${pkgver}/${pkgname}-${pkgver}.tar.xz)
sha256sums=(91e55a794f00fdb75305ed05f72a1ce310e228b115886f72471473c9c7c88960)

build() {
    cd ${pkgname}-${pkgver}

    cmake -B flarebird-build -Wno-dev                   \
          -DCMAKE_INSTALL_PREFIX=/usr         \
          -DCMAKE_INSTALL_LIBEXECDIR=libexec  \
          -DKDE_INSTALL_LIBDIR=lib64          \
          -DCMAKE_BUILD_TYPE=Release          \
          -DBUILD_QT5=OFF 

    cmake --build flarebird-build
}

package() {
    cd ${pkgname}-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build
}