pkgname=python-breezy
pkgver=3.3.9
pkgrel=1
pkgdesc="A decentralized revision control system with support for Bazaar and Git file formats"
arch=('x86_64')
url="https://www.breezy-vcs.org/"
license=('GPL-2.0-or-later')
depends=(
    'gcc-libs'
    'glibc'
    'python'
    'python-configobj'
    'python-dulwich'
    'python-fastbencode'
    'python-merge3'
    'python-patiencediff'
    'python-tzlocal'
    'python-pyyaml'
)
makedepends=(
    'python-cython'
    'python-build'
    'python-fastimport'
    'python-gpgme'
    'python-installer'
    'python-packaging'
    'python-paramiko'
    'python-setuptools'
    'python-setuptools-gettext'
    'python-setuptools-rust'
    'python-wheel'
)
source=(https://launchpad.net/brz/${pkgver%.*}/${pkgver}/+download/${pkgname#*-}-${pkgver}.tar.gz
    0001-Adapt-to-GPGME-handling-invalid-GPG-data-in-signatur.patch)
sha256sums=(c2588bf217c8a4056987ecf6599f0ad9fb8484285953b2e61905141f43c3d5d8
    3a1176252ec763983fa017d9fc70fcee38ecff5f2438b81dd3dbef66772b8c19)

prepare() {
    cd  ${pkgname#*-}-${pkgver}

    patch -Np1 -i ${srcdir}/0001-Adapt-to-GPGME-handling-invalid-GPG-data-in-signatur.patch
}

build() {
    cd  ${pkgname#*-}-${pkgver}

    python3 -m build --wheel --no-isolation
}

package() {
    cd  ${pkgname#*-}-${pkgver}

    python3 -m installer -d ${pkgdir} dist/*.whl

    ln -sv brz ${pkgdir}/usr/bin/bzr
}