pkgname=qt6-qtmultimedia
pkgver=6.7.0
pkgrel=1
pkgdesc="Classes for audio, video, radio and camera functionality"
arch=('x86_64')
url="https://www.qt.io"
license=('GPL3' 'LGPL3' 'FDL' 'custom')
groups=('qt6')
depends=('gcc-libs' 'glib2' 'glibc' 'gst-plugins-base' 'mesa' 'ffmpeg'
    'libx11' 'libxext' 'libxrandr' 'qt6-qtbase' 'pulseaudio')
makedepends=('cmake' 'ninja' 'qt6-qtdeclarative' 'qt6-qtquick3d' 'qt6-qtshadertools')
source=(https://download.qt.io/archive/qt/${pkgver%.*}/${pkgver}/submodules/${pkgname#*-}-everywhere-src-${pkgver}.tar.xz)
sha256sums=(f394bae49e3d4ee6a3b0c9e1e5e31bb870cc04a4b44f4cda3615baf7bd078c70)

build() {
    cd ${pkgname#*-}-everywhere-src-${pkgver}

    cmake -B flarebird-build -G Ninja                \
          -DCMAKE_BUILD_TYPE=Release       \
          -DCMAKE_INSTALL_PREFIX=/usr      \
          -DINSTALL_LIBDIR=lib64           \
          -DCMAKE_MESSAGE_LOG_LEVEL=STATUS \
          -DCMAKE_CXX_FLAGS="${CXXFLAGS} -ffat-lto-objects"

    cmake --build flarebird-build

}

package() {
    cd ${pkgname#*-}-everywhere-src-${pkgver}

    DESTDIR=${pkgdir} cmake --install flarebird-build
}