pkgname=qt6-qttools
pkgver=6.8.1
pkgrel=1
pkgdesc="A cross-platform application and UI framework (Development Tools, QtHelp)"
arch=('x86_64')
url="https://www.qt.io"
license=('GPL-3.0-only' 'LGPL-3.0-only' 'LicenseRef-Qt-Commercial' 'Qt-GPL-exception-1.0')
groups=('qt6')
depends=('gcc-libs' 'glibc' 'zstd' 'qt6-qtbase')
makedepends=('clang' 'cmake' 'git' 'litehtml' 'llvm' 'ninja' 'qt6-qtdeclarative')
source=(git+https://code.qt.io/qt/${pkgname#*-}#tag=v${pkgver}
        git+https://code.qt.io/playground/qlitehtml)
sha256sums=(7b1e6d811a5e2c0de54b439d64d8862153bdad82ba3d30b52dfdc2f44cb6a4de
    SKIP)

prepare() {
    cd ${pkgname#*-}

    git submodule init
    git submodule set-url src/assistant/qlitehtml ${srcdir}/qlitehtml
    git -c protocol.file.allow=always submodule update
}

build() {
    cd ${pkgname#*-}

    export CXXFLAGS+=" -ffat-lto-objects"

    cmake -B flarebird-build -G Ninja      \
          -DCMAKE_BUILD_TYPE=Release       \
          -DCMAKE_INSTALL_PREFIX=/usr      \
          -DINSTALL_LIBDIR=lib64           \
          -DCMAKE_MESSAGE_LOG_LEVEL=STATUS \
          -DINSTALL_PUBLICBINDIR=usr/bin

    cmake --build flarebird-build
}

package() {
    cd ${pkgname#*-}

    DESTDIR=${pkgdir} cmake --install flarebird-build

    # Install symlinks for user-facing tools
    cd ${pkgdir}
    mkdir usr/bin
    while read _line; do
        ln -s ${_line}
    done < ${srcdir}/${pkgname#*-}/flarebird-build/user_facing_tool_links.txt
}